project('pypaste')

fs = import('fs')

sources = files('pypaste/__init__.py')

modules = []

if get_option('client').enabled()
     sources += files(
       'pypaste/client/__init__.py',
       'pypaste/client/__main__.py',
       'pypaste/client/plugins/__init__.py',
       'pypaste/client/plugins/zen/__init__.py',
       'pypaste/client/plugins/pgz/__init__.py'       
     )

  modules += ['requests']
endif

if get_option('server').enabled()
     sources += files(
       'pypaste/server/__init__.py',
       'pypaste/server/__main__.py',
       'pypaste/server/s3/__init__.py',
       'pypaste/server/s3/bucket.py',
       'pypaste/server/sqlite/__init__.py'
     )

     modules += [
       'aiohttp',
       'aiosqlite',
       'zstandard',
       'pygments',
       'bozo4'
     ]
endif

python = import('python').find_installation(
  modules: modules
)

python.install_sources(sources, preserve_path: true)

if get_option('tests').enabled()
  pytest = find_program('pytest')

  test('unit_tests', pytest, args: sources)
  
  subdir('tests')
endif
     
# Local Variables:
# eval: (remove-hook 'before-save-hook 'fmt-current-buffer t)
# End: